LogiTrumps

A card game for the Atari 800.

# Description



LogiTrumps is a trump card game with retro computers. It’s like we used to play it in the 80ies. Each player (you and the computer) gets the same number of cards. Each card represents a retro computer and has several values like year, memory and colours. Each card has its strengths and weaknesses. If a computer has a lot of memory or colours, he usually is not that old and therefor would likely loose in the year category. Usually the higher value wins. The year category is the only category where the lower value wins. The player who gets all cards first wins the game.

# How to play

At the beginning of the game the cards are shuffled. You and the computer get the same number of cards. You can choose a category by typing the corresponding number. The program will calculate weather you won, lose or make a draw against the computers card. If you win, you get the computers card. If you lose the computer gets your card. If it’s a draw you keep your cards and just continue with the next card. If it’s the computers turn you can just watch what the computer choses and what happens.

# Emulator Usage

Run Altirra64.exe (or another emulator that supports copy and paste). Paste code with Alt+Shift+V. Run.

# Variables and Data Structures

|  |  |
| --- | --- |
| Variable | Usage |
| u | Users turn (1) or computer (0) |
| p[] | Person’s array for position of cards |
| c[] | Computer’s array for position of cards |
| r | Number of cards of person |
| e | Number of cards of computer |
| t$ | Name of cards (just a string, not an array) |
| a(card, factor) | Factors of the cards |
| p | Current position/card of person |
| c | Current position/card of computer |
| n | Round |
| b | Selected factor |
| z | Factor to print |

# Code

10 dim t$(100):t$="zx80 a500 c64 c16 a][ a400 cpc464c128 ":r=4:e=4:dim a(10,3):dim c(10):dim p(10)

20 ? chr$(125);"LogiTrumps":FOR i=1 TO 8:READ x,y,z:a(i,1)=x:a(i,2)=y:a(i,3)=z:p(i)=0:c(i)=0:next i:i=0:u=1:k=1

30 p=INT(RND(1)\*8)+1:x=not(c(p)+p(p)):p(p\*x)=(k)\*(k<5):c(p\*x)=(k-4)\*(k>4):k=k+x:if k<9 then goto 30

40 n=n+1:pp=0:cc=0:f. i=1 to 8:cc=cc+(c(i)=n)\*i:pp=pp+(p(i)=n)\*i:n. i:b=1+(a(cc,2)>16)\*2:? r;":";e:z=pp:GOSUB 100

50 IF u THEN ? "1-3: ";:input b

60 z=cc:GOSUB 100:? b:p(pp)=n+r:c(cc)=n+e:IF a(pp,b)>a(cc,b)THEN ?":-)":p(cc)=n+r+1:c(cc)=0:r=r+1:e=e-1:u=1

70 IF a(pp,b)<a(cc,b) THEN ?":-(":c(pp)=n+e+1:p(pp)=0:r=r-1:e=e+1:u=0

80 IF e<>0 AND r<>0 THEN goto 40

90 ? "\*\*\* GAME OVER \*\*\*":END:DATA 10,1,2, 3,512,4096, 8,64,16, 6,16,121, 13,4,15, 11,8,128, 6,64,27, 5,128,16

100 PRINT ">";t$(z\*6-5,z\*6):PRINT 1990-a(z,1):PRINT a(z,2);" kb ":print a(z,3);" cols":RETURN

# Code description

10 Initialize variables and name string.  
20 Print the title. Read the cards. Int variables.  
30 Shuffle the cards.  
40 Get the currently playing card’s positions. Calculate the selected category (for the computer player). Show score and display players card.  
50 Ask the user if it’s his turn for the category.  
60 Print computers card. Check if turn won and adapt cards and cards count.  
70 Check if turn lost and adapt cards and cards count.  
80 Game not over? Continue in 40.  
90 Game over. End.  
100 Print routine.

# Line lengths

Each line is shorter than 120 characters.

# Further Information

This program is part of a bigger project and available for different platforms. For more information check <https://logiker.com/LogiTrumps>.